プログラミング基礎 II

第十二回 (2010年 1月14日)

名前付きテンプレート

http://www.sw.it.aoyama.ac.jp/2009/PB2/lecture12.html

Martin J. Dürst

duerst@it.aoyama.ac.jp

© 2007-10 Martin J. Dürst 青山学院大学

今日の予定

• 前回の復習と演習
• 名前付きテンプレート
• テンプレートへの引数
• 変換への引数
• 演習

定期試験の予定

1 月18日 (月曜日) 3時限に最後の授業

1 月 25日 (月曜日) 3時限 (13:10-14:10)

過去の問題:

• 2007年度のミニテスト
• 2006年度の期末試験
• 2007年度の期末試験
• 閲覧には Opera を推奨
• スタイルの変更で正解例が見える

前々回の演習

本ごとの郵送料を計算する。注文のリストにそのための新しい欄を作る。本の全体の値段に足す。(詳細略)

ヒント (Test-Driven Development):

• テストのためのデータを作る (同じ本を別々に注文してもよい)
• 条件を構造的に分割する (例: 大まかに値段で分割; その中で本の数で分割)
• 少しずつ追加し、途中の結果をよく確認する

正解例: ordersShipping.xsl, その出力: ordersShipping.html

前回の復習

• コンピュータに処理させるときには繰り返しが多い
• XSLT では入力の分、<xsl:apply-templates> で自然に繰り返す
• 一部の場合には <xsl:for-each> で明記的な繰り返しが必要
• できるだけ自然な繰り返しを使って、「団子変換」を避けた方がよい

前回の演習

演習 1

本をテーブルとして出力する変換ファイルを次のように変更する:

• 見やすいように、行ごとに背景色を変える (例: 偶数行と奇数行に別の背景色)
• 簡単に書くように、<xsl:attribute> を使用する
• 何か決まった順番にする

正解例: tableStripes.xsl, その出力: resultStripes.html

演習 2

正解例: tableClump.xsl (出力は <xsl:apply-templates> を使ったものと変わらない)

順番の問題

問題:<xsl:template match='book[(position() mod 3) = 0]'> で分岐しようとすると、ソートがうまくできない

実例: tableStripesTemplate.xsl, その出力: tableStripesTemplate.html

理由:

• <xsl:template> の ＠match 内は XPath ではなく、パターン
• パターン内は position() などは元の文章内の位置で算出される

解決:

• 繰り返しは <xsl:apply-templates> でも <xsl:for-each> でも結構
• 分岐には @match ではなく、<xsl:choose> や <xsl:if>

名前付きテンプレートの目的

• 入力と別の処理をしたい
  (<xsl:apply-templates> などが使えない)
• 何回か同じ処理をしたい
  (<xsl:template> 見たいなものを使いたい)
• 引数によって違う処理をしたい
• 複雑な計算をしたい

名前付きテンプレートの基本形

• 名前付きテンプレートにも <xsl:template> 要素を使う
• @match の代わりに @name を使う
  (両方あってもよい)

<xsl:template name='greeting'>
  <p>Hello <strong>dear customer</strong>!</p>
</xsl:template>

名前付きテンプレートの呼び方

• <xsl:call-template> 要素を使う
• @name で呼びたいテンプレートを指定
• 使う場所:
  • <xsl:template> の中: 出力の一部を指定
  • <xsl:variable> の中: 変数の値の一部を指定

<xsl:template ...>
  ...
  <xsl:call-template name='greeting'/>
  ...
</xsl:template>

引数

parameter (ひきすう)

• やって欲しい仕事を細かく指定したい場合に使う
• <xsl:call-template> の中に <xsl:with-param> 要素を使う
• <xsl:template> の中 (一番最初) に <xsl:param> を使う
• <xsl:with-param> 要素で @name で引数の名前、@select 又は要素の内容で値を指定
• <xsl:param> 要素で@name で引数の名前、必要であれば @select 又は要素の内容で即定値を指定
• テンプレート内には引数は変数と同様に使える

引数の例

<xsl:template name='greeting'>
  <xsl:param name='who' select='"customer"'/>
  <p>Hello <strong>dear <xsl:value-of select='$who'/></strong>!</p>
</xsl:template>
 ...
<xsl:call-template name='greeting'>
  <xsl:with-param name='who'>青山 例子</xsl:with-param>
</xsl:call-template>

応用例: 階乗

• 自然数 n の階乗は n! で書き、n · (n-1) · (n-2) · ... · 2 · 1 で定義
• 実例:
  • 1! = 1
  • 2! = 2 · 1 = 2
  • 3! = 3 · 2 · 1 = 6
  • 4! = 4 · 3 · 2 · 1 = 24
  • 5! = 5 · 4 · 3 · 2 · 1 = 120
• 定義を少し替えることができる:
  • 1! = 1
  • n > 1 の場合、n! = n · (n-1)!

階乗を計算するテンプレート

<xsl:template name='階乗'>
  <xsl:param name='n'/>
  <xsl:choose>
    <xsl:when test='$n = 1'>1</xsl:when>
    <xsl:otherwise>
      <xsl:variable name='n1'>
        <xsl:call-template name='階乗'>
          <xsl:with-param name='n' select='$n - 1'/>
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of select='$n * $n1'/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

再帰

• テンプレートが同じ名前のテンプレートを呼ぶことは再帰 (recursion) という
• 情報テクノロジーで良く使用
• 今までにも使うことができた
  例: 入力の <div> の中の <div> で、<xsl:template match='div'> が再帰的に使用
• 同じものを呼ぶとぃうより同名の同様な (しかし別の) ものを呼ぶ
• 深く考える必要がない!

<xsl:param> のもう一つの使い方

• 変換全体に引数を渡すことができる
• <xsl:transform> (又は <xsl:stylesheet>) 直下で <xsl:param> を使う
• 指定は実装による
• msxsl の場合:
  Z:\>msxsl data.xml transform.xsl name=value >result.html

演習 1

1. 応用例 (階乗) を使った変換ファイルを作成し、何かの数字の階乗を計算してください

   ヒント:

   • 入力のデータファイルは何でもよい
   • ルートノード用の <xsl:template> が必要
   • 出力は綺麗な (X)HTML にして下さい
   • 最初は n は変換ファイルの中に固定してよい
2. 1. の変更で n を変換ファイルの外から指定できるようにする

正解例: fac.xsl

演習 2

提出: 1月17日 (日曜日) 22:00 までに Moodle に投稿

(例えば新年とか成人式の) 挨拶文を (X)HTML で出力する変換ファイルを作る。

相手の名前と挨拶文の回数は外側から指定できるようにする。

ヒント: 「n 回の挨拶文」を階乗と同じように定義しなおす。

次回への準備

授業全体の内容を復習し、分からない部分をリストアップ